환경 : Microsoft 365 / Excel 2010 이상
주문번호에서 연도만, 이메일에서 아이디만, 전화번호에서 뒷자리만 뽑아야 할 때 쓰는 기본 텍스트 함수 LEFT, RIGHT, MID, LEN을 정리합니다.
1. 사용 방법
| 함수 | 형식 | 하는 일 |
|---|---|---|
| LEFT | =LEFT(text, [num_chars]) | 왼쪽에서 n글자 |
| RIGHT | =RIGHT(text, [num_chars]) | 오른쪽에서 n글자 |
| MID | =MID(text, start_num, num_chars) | n번째 글자부터 m글자 |
| LEN | =LEN(text) | 글자 수 (공백 포함) |
LEFT·RIGHT에서 글자 수를 생략하면 1글자만 가져옵니다.
2. 예제 데이터
| A | B | C | |
|---|---|---|---|
| 1 | 주문번호 | 전화번호 | 이메일 |
| 2 | 2026-SE-0153 | 010-1234-5678 | namik@example.com |
| 3 | 2025-BS-0042 | 010-9876-5432 | hello.world@test.co.kr |
예제 ① 주문번호 나누기 (위치가 고정된 경우)
| 원하는 값 | 수식 | 결과 |
|---|---|---|
| 연도 | =LEFT(A2, 4) | 2026 |
| 지역 코드 | =MID(A2, 6, 2) | SE |
| 일련번호 | =RIGHT(A2, 4) | 0153 |
| 전체 글자 수 | =LEN(A2) | 12 |
예제 ② 전화번호 가운데 가리기
=LEFT(B2, 4) & "****" & RIGHT(B2, 5)
결과는 010-****-5678입니다. 앞 4글자(010-)와 뒤 5글자(-5678)를 &로 이어 붙였습니다.
예제 ③ 이메일 아이디·도메인 (위치가 바뀌는 경우)
아이디 길이는 사람마다 다르므로 @의 위치를 FIND로 찾아 기준으로 삼습니다. FIND는 FIND 함수(131번 글)를 참고하세요.
아이디 : =LEFT(C2, FIND("@", C2) - 1)
도메인 : =MID(C2, FIND("@", C2) + 1, LEN(C2))
첫 행은 namik과 example.com, 둘째 행은 hello.world와 test.co.kr이 나옵니다. MID의 글자 수에 LEN(C2)처럼 넉넉한 값을 넣으면 '끝까지'라는 뜻이 됩니다.
[캡처 : 이메일 분리 결과]
3. 주의사항
1. 잘라낸 결과는 텍스트입니다. LEFT(A2,4)의 2026은 숫자처럼 보여도 계산·비교가 안 될 수 있으니 =VALUE(LEFT(A2,4)) 또는 =--LEFT(A2,4)로 숫자로 바꾸세요.
2. 앞뒤 공백이 섞여 있으면 위치가 어긋납니다. TRIM으로 먼저 정리하세요. 예 : =LEFT(TRIM(A2), 4)
3. 숫자 셀(예 : 날짜)에 쓰면 표시 형식이 아니라 내부 숫자를 자릅니다. 날짜는 YEAR, MONTH 함수를 쓰세요.
4. Microsoft 365라면
=TEXTSPLIT(A2, "-") → 2026 | SE | 0153 으로 한 번에 분리
=TEXTBEFORE(C2, "@") → 아이디
=TEXTAFTER(C2, "@") → 도메인
구분 기호가 있는 데이터는 위치를 계산할 필요 없이 바로 나눌 수 있습니다. 주소에서 동 이름을 뽑는 예제는 SEARCH 함수(135번 글)에 있습니다.